Linear elasticity

Example from Landau-Lifschitz, Theory of elasticity, volume 7, Pergaom Press, 1970.

Let us introduce the following Ore algebra A of partial differential operators

A=OreAlgebra[Der[x], Der[y],Der[z]]

and the matrix R of partial differential operators, which defines the equilibrium of the stress tensor (forces are absent)

R={{Der[x],0,0,0,Der[z],Der[y]},
{0,Der[y],0,Der[z],0,Der[x]},
{0,0,Der[z],Der[y],Der[x],0}};
MatrixForm[R=ToOrePolynomial[R,A]]

and the left A-module, finitely presented by R, defined by M = (A^(1×6))/(A^(1×3))R.

Let us write the equations of the system explicitly:

u={x,y,z};
EMF={(Subscript[σ, 1])@@u,(Subscript[σ, 2])@@u,(Subscript[σ, 3])@@u,(Subscript[τ, 1])@@u,(Subscript[τ, 2])@@u,(Subscript[τ, 3])@@u}

sys=Thread[ApplyMatrix[R, EMF]==0]

Let us compute the adjoint of R:

MatrixForm[Radj=Involution[R,A]]

Let us check whether or not M is torsion-free:

MatrixForm/@({Ann,Rp,Q}=Exti[Radj,A,1])

Since the first matrix is identity, M is torsion-free and thus the system is parametrized by Q, i.e:

Thread[EMF==ApplyMatrix[Q,{(Subscript[θ, 1])@@u,(Subscript[θ, 2])@@u,(Subscript[θ, 3])@@u,(Subscript[ψ, 1])@@u,(Subscript[ψ, 2])@@u,(Subscript[ψ, 3])@@u}]]

We note the above parametrization involves six arbitrary functions (Subscript[θ, 1]),(Subscript[θ, 2]),(Subscript[θ, 3]), (Subscript[ψ, 1]), (Subscript[ψ, 2]), (Subscript[ψ, 3]). Let us now compute the rank of the system

OreRank[R,A]

From that we know that there exist parametrizations involving only three arbitrary functions. Let us compute two of them leading to standard parametrizations:

MatrixForm[Q1=#[[{1,3,5}]]&/@Q]

ColumnForm@ApplyMatrix[Q1,{(Subscript[ψ, 3])[x,y,z]/2,(Subscript[ψ, 2])[x,y,z]/2,-(Subscript[ψ, 1])[x,y,z]/2}]

This is the Morera parametrization.

MatrixForm[Q2=#[[{2,4,6}]]&/@Q]

ColumnForm@ApplyMatrix[Q2,{(Subscript[θ, 1])[x,y,z],(Subscript[θ, 2])[x,y,z],(Subscript[θ, 3])[x,y,z]}]

This is the Maxwell parametrization.